#define scr_menu_init
//scr_menu made by Martin Larsson 2008 (martin.kj.larsson@telia.com)
//version 1

//DEFINING MENU VARIABLES
//public variables
menu_base_x=room_width/2; //x-origin
menu_base_y=50; //y-origin
menu_base_width=96; //Default width
menu_base_height=32; //Default height
menu_base_xscale=1.5; //Top x-scale limit (1=no scaling)
menu_base_yscale=1.5; //Top y-scale limit (1=no scaling)
menu_base_xspeed=20; //The x-speed of scaling (1=no speed)
menu_base_yspeed=20; //The y-speed of scaling (1=no speed)
menu_base_halign=0; //The horizontal alignment of the buttons (-1=left, 0=center, 1=right)
menu_base_separate=8; //The distance between the buttons
menu_base_number=5; //Number of buttons
menu_base_font=font_menu; //The font used when drawing the text
menu_base_dots=true; //Whether to show dots when the string is to long or not
menu_base_color_text=c_black; //Text color
menu_base_color_outline=c_black; //Outline color
menu_base_color_normal=c_yellow; //Normal color
menu_base_color_hover=make_color(255,255,192); //Color when the mouse is hovering over the button
menu_base_color_pressed=c_olive; //Color when the mouse is pressed on the button
menu_base_fade=96; //The amount of shade on the button
menu_base_shade=0.5; //The anpha amount on the shade from the button (0=no shade)
menu_base_shade_xoffset=4; //The x-offset of the shade
menu_base_shade_yoffset=4; //The y-offset of the shade

//private variables
for (i=0;i<menu_base_number;i+=1)
{
    menu_x[i]=menu_base_x-menu_base_width/2; //The start x
    menu_y[i]=menu_base_y + i*(menu_base_height+menu_base_separate); //The start y
    
    menu_width[i]=menu_base_width; //The start width
    menu_height[i]=menu_base_height; //The start height
    
    menu_xscale[i]=1; //The start x-scale
    menu_yscale[i]=1; //The start y-scale
    
    menu_color_fill[i]=menu_base_color_normal; //The start color for filling
}

//Text for the buttons
menu_text[0]="First";
menu_text[1]="Second";
menu_text[2]="Third";
menu_text[3]="Fourth";
menu_text[4]="Fifth";

#define scr_menu_step
//returns the index of the button that has been pressed (-1=noone)
var count_y,re;
count_y=0;
re=-1;
for (i=0;i<menu_base_number;i+=1)
{
    //If the mouse is hovering over the button
    if (mouse_x>=menu_x[i] and mouse_x<menu_x[i]+menu_width[i] and mouse_y>=menu_y[i] and mouse_y<menu_y[i]+menu_height[i])
    {
        //If the buttons has been pressed and is now released
        if (mouse_check_button_released(mb_left) and menu_color_fill[i]=menu_base_color_pressed)
            re=i;
        //If the mouse is pressed the color changes
        if (mouse_check_button_pressed(mb_left))
            menu_color_fill[i]=menu_base_color_pressed;
        else if (mouse_check_button(mb_left)=false)
            menu_color_fill[i]=menu_base_color_hover;
        
        //If the mouse is hovering over the button the size increases
        if (menu_xscale[i]<menu_base_xscale)
            menu_xscale[i]+=menu_base_xscale/menu_base_xspeed;
        if (menu_yscale[i]<menu_base_yscale)
            menu_yscale[i]+=menu_base_yscale/menu_base_yspeed;
    }
    else
    {
        //Else the color is normal and the size decreases
        menu_color_fill[i]=menu_base_color_normal;
        if (menu_xscale[i]>1)
            menu_xscale[i]-=menu_base_xscale/menu_base_xspeed;
        if (menu_yscale[i]>1)
            menu_yscale[i]-=menu_base_yscale/menu_base_yspeed;
    }

    //Adjust the scale so it wont get under 1
    if (menu_xscale[i]<1+menu_base_xscale/menu_base_xspeed/4)
        menu_xscale[i]=1;
    if (menu_yscale[i]<1+menu_base_yscale/menu_base_yspeed/4)
        menu_yscale[i]=1;
    
    //Adjust the scale so it wont get over the top scale limit
    if (menu_xscale[i]>menu_base_xscale-menu_base_xscale/menu_base_xspeed/4)
        menu_xscale[i]=menu_base_xscale;
    if (menu_yscale[i]>menu_base_yscale-menu_base_yscale/menu_base_yspeed/4)
        menu_yscale[i]=menu_base_yscale;

    //Setting the x- and y-coordinates
    if (menu_base_halign=-1)
        menu_x[i]=floor(menu_base_x-menu_base_width*menu_xscale[i]);
    else if (menu_base_halign=0)
        menu_x[i]=floor(menu_base_x-menu_base_width*menu_xscale[i]/2);
    else if (menu_base_halign=1)
        menu_x[i]=menu_base_x;
    menu_y[i]=menu_base_y+count_y;
    
    //Setting the width and height
    menu_width[i]=floor(menu_xscale[i]*menu_base_width);
    menu_height[i]=floor(menu_yscale[i]*menu_base_height);
    
    //Increases count_y to move on to the next button
    count_y+=menu_height[i]+menu_base_separate;
}

return re;
#define scr_menu_draw
draw_set_halign(fa_center);
draw_set_valign(fa_middle);

//Making the shade
if (menu_base_shade>0)
{
    draw_set_color(c_black);
    draw_set_alpha(menu_base_shade);
    for (i=0;i<menu_base_number;i+=1)
    {  
        draw_rectangle(menu_x[i]+menu_base_shade_xoffset,menu_y[i]+menu_base_shade_yoffset,menu_x[i]+menu_width[i]+menu_base_shade_xoffset,menu_y[i]+menu_height[i]+menu_base_shade_yoffset,false);
    }
}
draw_set_alpha(1);

for (i=0;i<menu_base_number;i+=1)
{
    //Outline
    draw_set_color(menu_base_color_outline);
    draw_rectangle(menu_x[i],menu_y[i],menu_x[i]+menu_width[i],menu_y[i]+menu_height[i],true);
    //Filling
    color1=menu_color_fill[i];
    color2=make_color_hsv(color_get_hue(color1),color_get_saturation(color1),color_get_value(color1)-menu_base_fade)
    draw_rectangle_color(menu_x[i]+1,menu_y[i]+1,menu_x[i]+menu_width[i]-1,menu_y[i]+menu_height[i]-1,color1,color1,color2,color2,false);
    //Text
    draw_set_color(menu_base_color_text);
    draw_set_font(menu_base_font);
    //If the text fit inside the button
    if (string_width(menu_text[i])<menu_width[i]-8 and string_height(menu_text[i])<menu_height[i]-8 and menu_text[i]!="")
    {
        draw_text(menu_x[i]+menu_width[i]/2,menu_y[i]+menu_height[i]/2,menu_text[i]);
    }
    //If it's posible to draw any text at all
    else if (string_width("...")<menu_width[i]-8 and string_height("ONE_LINE")<menu_height[i]-8)
    {
        var word,count;
        word=menu_text[i];
        count=string_length(menu_text[i]);
        
        if (menu_base_dots=true) //Dots at the end
        {
            while (string_width(word+"...")>menu_width[i]-8 or string_height(word+"...")>menu_height[i]-8)
            {
                //Takes away the last letter until the text fit inside the button
                word=string_copy(menu_text[i],1,count);
                count-=1;
            }
            word=word+"...";
        }
        else //No dots at the end
        {
            while (string_width(word)>menu_width[i]-8 or string_height(word)>menu_height[i]-8)
            {
                word=string_copy(menu_text[i],1,count);
                count-=1;
            }
        }
        draw_text(menu_x[i]+menu_width[i]/2,menu_y[i]+menu_height[i]/2,word);
    }
}
#define scr_menu_hover
//returns the index of the button that the mouse hovers over (-1=noone)

for (i=0;i<menu_base_number;i+=1)
{
    //If the mouse is hovering over the button
    if (mouse_x>=menu_x[i] and mouse_x<menu_x[i]+menu_width[i] and mouse_y>=menu_y[i] and mouse_y<menu_y[i]+menu_height[i])
    {
        return i;
    }
}
return -1;